Net.idl

#include <Event.idl>

module net {

    structure IpAddrCidr {
        string                  addr;                   // IP address
        int                     prefixLen;              // Length of network prefix in the IP address
    };

    structure IpRoute {
        IpAddrCidr              destNetAddrCidr;        // Destination network address (CIDR)
        string                  nextHopAddr;            // Address of the next hop (empty when ifName is set)
        string                  ifName;                 // Destination interface (empty if nextHopAddr is set)
    };

    enumeration PortForwardingRole {
        MASTER,                                         
        SLAVE                                           
    };
    
    [sparse_in]
    structure PortForwardingSettings_2_0_0 {
        boolean                 enabled;                
        PortForwardingRole      role;                   
        string                  masterDownstreamIfName; 
    };

    [sparse_in]
    structure DnsSettings_2_0_0 {
        vector<string>          serverAddrs;            
        vector<string>          searchSuffixes;         
        boolean                 resolverPrefersIPv6;    
    };

    [sparse_in]
    structure IpRoutingSettings_2_0_0 {
        string                  defaultGatewayAddr;     
        vector<IpRoute>         staticRoutes;           
    };

    [sparse_in]
    structure RoutingSettings_2_0_0 {
        IpRoutingSettings_2_0_0 ipv4;                   
        IpRoutingSettings_2_0_0 ipv6;                   
    };

    [sparse_in]
    structure CommonSettings_2_0_0 {
        DnsSettings_2_0_0               dns;            
        RoutingSettings_2_0_0           routing;        
        PortForwardingSettings_2_0_0    portForwarding; 
    };
        
    structure PortForwardingMasterAddrInfo {
        string                  ifName;                 
        string                  addr;                   
    };

    structure PortForwardingInfo {
        boolean                 enabled;                
        boolean                 nodeIndexValid;         
        int                     nodeIndex;              
        boolean                 slaveConnected;         
        string                  masterDownstreamIfName; 
        vector<PortForwardingMasterAddrInfo> masterIPv4AddrInfos; 
        vector<PortForwardingMasterAddrInfo> masterIPv6AddrInfos; 
    };

    structure DnsInfo {
        vector<string>          serverAddrs;            
        vector<string>          searchSuffixes;         
        boolean                 resolverPrefersIPv6;    
    };

    structure RoutingInfo {
        vector<IpRoute>         ipv4Routes;             
        vector<IpRoute>         ipv6Routes;             
    };

    structure CommonInfo {
        DnsInfo                 dns;                    
        RoutingInfo             routing;                
        PortForwardingInfo      portForwarding;         
    };

    enumeration IpConfigMethod {
        STATIC,                                         
        DHCP,                                           
        AUTO                                            
    };

    [sparse_in]
    structure InterfaceIpSettings_2_0_0 {
        boolean                 enabled;                
        IpConfigMethod          configMethod;           
        IpAddrCidr              staticAddrCidr;         
        string                  dhcpPreferredHostname;  
    };

    structure InterfaceIPv4Info {
        boolean                 enabled;                
        IpConfigMethod          configMethod;           
        vector<IpAddrCidr>      addrsCidr;              
        string                  dhcpServerAddr;         
        string                  dhcpPreferredHostname;  
    };

    structure InterfaceIPv6Info {
        boolean                 enabled;                
        IpConfigMethod          configMethod;           
        vector<IpAddrCidr>      addrsCidr;              
        string                  dhcpServerId;           
        string                  dhcpPreferredHostname;  
        boolean                 raManaged;              
        boolean                 raOtherConf;            
    };

    [sparse_in]
    structure InterfaceSettings_2_0_0 {
        boolean                         enabled;        
        InterfaceIpSettings_2_0_0       ipv4;           
        InterfaceIpSettings_2_0_0       ipv6;           
    };

    enumeration InterfaceType {
        ETHERNET,                                       
        WLAN,                                           
        BRIDGE                                          
    };

    enumeration InterfaceOpState {
        NOT_PRESENT,                                    
        DOWN,                                           
        NO_LINK,                                        
        UP                                              
    };

    structure InterfaceInfo {
        string                  name;                   
        string                  label;                  
        InterfaceType           type;                   
        boolean                 enabled;                
        string                  masterIfName;           
        InterfaceOpState        state;                  
        string                  macAddr;                
        InterfaceIPv4Info       ipv4;                   
        InterfaceIPv6Info       ipv6;                   
    };

    enumeration EthSpeed {
        SPEED_AUTO,                                     
        SPEED_MBIT_10,                                  
        SPEED_MBIT_100,                                 
        SPEED_MBIT_1000                                 
    };

    enumeration EthDuplexMode {
        DUPLEX_MODE_AUTO,                               
        DUPLEX_MODE_HALF,                               
        DUPLEX_MODE_FULL                                
    };

    structure EthLinkMode {
        EthSpeed                speed;                  
        EthDuplexMode           duplexMode;             
    };

    structure EthSettings {
        EthLinkMode             linkMode;               
    };

    structure EthInfo {
        EthLinkMode             linkMode;               
        boolean                 linkModeValid;          
        boolean                 autonegEnabled;         
        boolean                 linkDetected;           
        vector<EthLinkMode>     supportedLinkModes;     
    };

    enumeration WlanSecProtocol {
        WPA2                                            
    };

    enumeration WlanAuthType {
        NONE,                                           
        PSK,                                            
        EAP                                             
    };

    enumeration EapOuterAuthMethod {
        PEAP                                            
    };

    enumeration EapInnerAuthMethod {
        MSCHAPv2                                        
    };

    [sparse_in]
    structure EapAuthSettings_2_0_0 {
        string                  identity;               
        string                  password;               
        boolean                 clearPassword;          
        EapOuterAuthMethod      outerMethod;            
        EapInnerAuthMethod      innerMethod;            
        string                  caCertChain;            
        boolean                 forceTrustedCert;       
        boolean                 allowOffTimeRangeCerts; 
        boolean                 allowNotYetValidCertsIfTimeBeforeBuild; 
        string                  authServerName;         
    };

    [sparse_in]
    structure WlanSettings_2_0_0 {
        boolean                 enableHT;               
        string                  ssid;                   
        string                  bssid;                  
        WlanSecProtocol         secProtocol;            
        WlanAuthType            authType;               
        string                  psk;                    
        boolean                 clearPsk;               
        EapAuthSettings_2_0_0   eap;                    
    };

    enumeration WlanChannelWidth {
        CHANNEL_WIDTH_UNKNOWN,
        CHANNEL_WIDTH_20_NO_HT,
        CHANNEL_WIDTH_20,
        CHANNEL_WIDTH_40,
        CHANNEL_WIDTH_80,
        CHANNEL_WIDTH_80P80,
        CHANNEL_WIDTH_160
    };

    structure WlanInfo {
        boolean                 associated;             
        string                  ssid;                   
        string                  bssid;                  
        int                     channel;                
        WlanChannelWidth        channelWidth;           
    };

    [sparse_in]
    structure Settings_2_0_0 {
        CommonSettings_2_0_0                    common; 
        map<string, InterfaceSettings_2_0_0>    ifMap;  
        map<string, EthSettings>                ethMap; 
        map<string, WlanSettings_2_0_0>         wlanMap;
    };

    structure Info {
        CommonInfo                      common;         
        map<string, InterfaceInfo>      ifMap;          
        map<string, EthInfo>            ethMap;         
        map<string, WlanInfo>           wlanMap;        
    };

    structure PortForwardingProtocolMapping {
        int appProtoId;                                 
        string appProtoName;                            
        string transportProtoName;                      
    };

    /* ---- event definitions ---- */

    valueobject CommonInfoChangedEvent extends idl.Event {
        CommonInfo commonInfo;                          
    };

    valueobject InterfaceInfoChangedEvent extends idl.Event {
        InterfaceInfo ifInfo;                           
    };

    valueobject EthInfoChangedEvent extends idl.Event {
        string ifName;                                  
        EthInfo ethInfo;                                
    };

    valueobject WlanInfoChangedEvent extends idl.Event {
        string ifName;                                  
        WlanInfo wlanInfo;                              
    };

    valueobject LinkStateChangedEvent extends idl.Event {
        string ifName;                                  
        string ifLabel;                                 
        InterfaceType ifType;                           
        InterfaceOpState ifState;                       
    };

    valueobject PortForwardingSlavePresenceStateChangedEvent extends idl.Event {
        boolean slavePresent;                           
    };

    interface Net_4_0_1 {

        constant int SUCCESS                                    = 0;
        
        constant int ERR_DNS_TOO_MANY_SERVERS                   = 100;
        constant int ERR_DNS_INVALID_SERVER                     = 101;
        constant int ERR_DNS_TOO_MANY_SEARCH_SUFFIXES           = 102;
        constant int ERR_DNS_INVALID_SEARCH_SUFFIX              = 103;

        constant int ERR_ROUTING_IPV4_INVALID_DFLT_GATEWAY_ADDR = 200;
        constant int ERR_ROUTING_IPV6_INVALID_DFLT_GATEWAY_ADDR = 201;
        constant int ERR_ROUTING_IPV4_INVALID_DEST_ADDR         = 202;
        constant int ERR_ROUTING_IPV6_INVALID_DEST_ADDR         = 203;
        constant int ERR_ROUTING_IPV4_INVALID_DEST_PREFIX_LEN   = 204;
        constant int ERR_ROUTING_IPV6_INVALID_DEST_PREFIX_LEN   = 205;
        constant int ERR_ROUTING_IPV4_INVALID_NEXTHOP_ADDR      = 206;
        constant int ERR_ROUTING_IPV6_INVALID_NEXTHOP_ADDR      = 207;
        constant int ERR_ROUTING_IPV4_INVALID_INTERFACE         = 208;
        constant int ERR_ROUTING_IPV6_INVALID_INTERFACE         = 209;
        constant int ERR_ROUTING_IPV4_DEST_IS_NO_NETWORK_ADDR   = 210;
        constant int ERR_ROUTING_IPV6_DEST_IS_NO_NETWORK_ADDR   = 211;
        constant int ERR_ROUTING_IPV4_DEST_IS_DUPLICATE         = 212;
        constant int ERR_ROUTING_IPV6_DEST_IS_DUPLICATE         = 213;
        constant int ERR_ROUTING_IPV4_NO_NEXTHOP_OR_INTERFACE   = 214;
        constant int ERR_ROUTING_IPV6_NO_NEXTHOP_OR_INTERFACE   = 215;
        constant int ERR_ROUTING_IPV4_NEXTHOP_AND_INTERFACE_SET = 216;
        constant int ERR_ROUTING_IPV6_NEXTHOP_AND_INTERFACE_SET = 217;

        constant int ERR_PF_INVALID_MASTER_DOWNSTREAM_INTERFACE = 300;
        constant int ERR_PF_NO_WORKING_MASTER_UPSTREAM_INTERFACE= 301;

        constant int ERR_IF_IPV4_INVALID_CONFIG_METHOD          = 400;
        constant int ERR_IF_IPV6_INVALID_CONFIG_METHOD          = 401;
        constant int ERR_IF_IPV4_INVALID_STATIC_ADDR            = 402;
        constant int ERR_IF_IPV6_INVALID_STATIC_ADDR            = 403;
        constant int ERR_IF_IPV4_INVALID_STATIC_PREFIX_LEN      = 404;
        constant int ERR_IF_IPV6_INVALID_STATIC_PREFIX_LEN      = 405;
        constant int ERR_IF_IPV4_INVALID_DHCP_PREF_HOSTNAME     = 406;
        constant int ERR_IF_IPV6_INVALID_DHCP_PREF_HOSTNAME     = 407;

        constant int ERR_ETH_IF_UNSUPPORTED_LINKMODE            = 500;

        constant int ERR_WLAN_IF_INVALID_SSID                   = 600;
        constant int ERR_WLAN_IF_INVALID_BSSID                  = 601;
        constant int ERR_WLAN_IF_INVALID_PSK                    = 602;
        constant int ERR_WLAN_IF_INVALID_EAP_IDENTITY           = 603;
        constant int ERR_WLAN_IF_INVALID_EAP_PASSWORD           = 604;
        constant int ERR_WLAN_IF_INVALID_EAP_CERT               = 605;
        constant int ERR_WLAN_IF_EAP_CERT_VERIFY_FAILED         = 606;
        constant int ERR_WLAN_IF_INVALID_EAP_AUTH_SERVER_NAME   = 607;

        Info getInfo();

        Settings_2_0_0 getSettings();

        int setSettings(in Settings_2_0_0 settings);

        vector<PortForwardingProtocolMapping> getPortForwardingProtocolMappings();

    };

}